mirror of
https://github.com/apple/pkl.git
synced 2026-04-27 02:38:41 +02:00
4faf35a66a
Motivation: buildSrc is a special-case legacy mechanism. Gradle recommends using an included build named build-logic instead: https://docs.gradle.org/current/userguide/best_practices_structuring_builds.html#favor_composite_builds Changes: - Rename buildSrc/ to build-logic/ - triggers reformatting - Replace occurrences of "buildSrc" with "build-logic" - Include the build-logic build in the main build (via settings.gradle.kts) - Apply convention plugins via plugin IDs instead of type-safe accessors - small tradeoff compared to buildSrc Result: - Faster and more isolated builds - Build logic behaves like a normal build, making it easier to evolve and reason about --------- Co-authored-by: Daniel Chao <dan.chao@apple.com>
85 lines
2.4 KiB
Kotlin
85 lines
2.4 KiB
Kotlin
/*
|
|
* Copyright © 2024-2026 Apple Inc. and the Pkl project authors. All rights reserved.
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* https://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
plugins {
|
|
id("pklAllProjects")
|
|
id("pklKotlinLibrary")
|
|
id("pklNativeLifecycle")
|
|
}
|
|
|
|
dependencies {
|
|
implementation(projects.pklCore)
|
|
implementation(libs.msgpack)
|
|
implementation(libs.truffleApi)
|
|
|
|
testImplementation(projects.pklCommonsTest)
|
|
}
|
|
|
|
tasks.test { exclude("**/NativeServerTest.*") }
|
|
|
|
private fun Test.configureNativeTest() {
|
|
testClassesDirs = files(tasks.test.get().testClassesDirs)
|
|
classpath = tasks.test.get().classpath
|
|
include("**/NativeServerTest.*")
|
|
}
|
|
|
|
val testMacExecutableAarch64 by
|
|
tasks.registering(Test::class) {
|
|
dependsOn(":pkl-cli:macExecutableAarch64")
|
|
configureNativeTest()
|
|
}
|
|
|
|
val testMacExecutableAmd64 by
|
|
tasks.registering(Test::class) {
|
|
dependsOn(":pkl-cli:macExecutableAmd64")
|
|
configureNativeTest()
|
|
}
|
|
|
|
val testLinuxExecutableAmd64 by
|
|
tasks.registering(Test::class) {
|
|
dependsOn(":pkl-cli:linuxExecutableAmd64")
|
|
configureNativeTest()
|
|
}
|
|
|
|
val testLinuxExecutableAarch64 by
|
|
tasks.registering(Test::class) {
|
|
dependsOn(":pkl-cli:linuxExecutableAarch64")
|
|
configureNativeTest()
|
|
}
|
|
|
|
val testAlpineExecutableAmd64 by
|
|
tasks.registering(Test::class) {
|
|
dependsOn(":pkl-cli:alpineExecutableAmd64")
|
|
configureNativeTest()
|
|
}
|
|
|
|
val testWindowsExecutableAmd64 by
|
|
tasks.registering(Test::class) {
|
|
dependsOn(":pkl-cli:windowsExecutableAmd64")
|
|
configureNativeTest()
|
|
}
|
|
|
|
tasks.testNativeMacOsAarch64 { dependsOn(testMacExecutableAarch64) }
|
|
|
|
tasks.testNativeMacOsAmd64 { dependsOn(testMacExecutableAmd64) }
|
|
|
|
tasks.testNativeLinuxAarch64 { dependsOn(testLinuxExecutableAarch64) }
|
|
|
|
tasks.testNativeLinuxAmd64 { dependsOn(testLinuxExecutableAmd64) }
|
|
|
|
tasks.testNativeAlpineLinuxAmd64 { dependsOn(testAlpineExecutableAmd64) }
|
|
|
|
tasks.testNativeWindowsAmd64 { dependsOn(testWindowsExecutableAmd64) }
|