refactor: start i3/hyprland in home-manager instead of NixOS

2026-05-28 10:29:29 +02:00 · 2023-12-23 13:33:47 +08:00
parent 82cfa4c6f7
commit 73e3707570
20 changed files with 370 additions and 134 deletions
@@ -0,0 +1,31 @@
+{
+  pkgs,
+  config,
+  lib,
+  wallpapers,
+  ...
+}: {
+  systemd.user.services.wallpaper = {
+    Unit = {
+      Description = "Wallpaper Switcher daemon";
+      After = ["graphical-session-pre.target" "xdg-desktop-autostart.target"];
+      Wants = ["graphical-session-pre.target"];
+    };
+    Install.WantedBy = ["graphical-session.target"];
+    Service = {
+      ExecStart = lib.getExe (pkgs.writeShellApplication {
+        name = "wallpaper";
+        runtimeInputs = with pkgs; [procps feh swaybg python3];
+        text = ''
+          export WALLPAPERS_DIR="${wallpapers}"
+          export WALLPAPERS_STATE_FILEPATH="${config.xdg.stateHome}/wallpaper-switcher/switcher_state"
+          export WALLPAPER_WAIT_MIN=10
+          export WALLPAPER_WAIT_MAX=20
+          exec ${./wallpaper-switcher.py}
+        '';
+      });
+      RestartSec = 3;
+      Restart = "on-failure";
+    };
+  };
+}