mirror of
https://github.com/apple/pkl.git
synced 2026-06-10 15:52:50 +02:00
Daniel Chao
1cc20b611f
This reverts the commits that enabled Gradle's configuration cache feature. IMO: this feature is too hard to use. We don't know if a task is valid for the configuration cache until it runs, and it's very hard to tell if something is safe when authoring Gradle code. For example, our publish tasks are currently failing; I don't know how I would fix this without running the publish task again on my dev machine. Also, some of our build scripts become more brittle because of this; for example, see https://github.com/apple/pkl/blob/bb07589eae0b3195a589559a3245cbc12c29b394/build-logic/src/main/kotlin/BuildInfo.kt#L291-L296
119 lines
3.7 KiB
Kotlin
119 lines
3.7 KiB
Kotlin
/*
|
|
* Copyright © 2024-2026 Apple Inc. and the Pkl project authors. All rights reserved.
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* https://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
plugins {
|
|
id("pklAllProjects")
|
|
id("pklJavaLibrary")
|
|
id("pklFatJar")
|
|
id("pklPublishLibrary")
|
|
id("pklJSpecify")
|
|
signing
|
|
}
|
|
|
|
val pklCodegenJava: Configuration by configurations.creating
|
|
val firstPartySourcesJars by configurations.existing
|
|
|
|
val generateTestConfigClasses by
|
|
tasks.registering(JavaExec::class) {
|
|
val outputDir = layout.buildDirectory.dir("testConfigClasses")
|
|
outputs.dir(outputDir)
|
|
inputs.dir("src/test/resources/codegenPkl")
|
|
|
|
classpath = pklCodegenJava
|
|
mainClass.set("org.pkl.codegen.java.Main")
|
|
argumentProviders.add(
|
|
CommandLineArgumentProvider {
|
|
listOf("--output-dir", outputDir.get().asFile.path, "--generate-javadoc") +
|
|
fileTree("src/test/resources/codegenPkl").map { it.path }
|
|
}
|
|
)
|
|
}
|
|
|
|
tasks.processTestResources { dependsOn(generateTestConfigClasses) }
|
|
|
|
tasks.compileTestKotlin { dependsOn(generateTestConfigClasses) }
|
|
|
|
val bundleTests by tasks.registering(Jar::class) { from(sourceSets.test.get().output) }
|
|
|
|
// Runs unit tests using jar'd class files as a source.
|
|
// This is to test loading the ClassRegistry from within a jar, as opposed to directly from the file
|
|
// system.
|
|
val testFromJar by
|
|
tasks.registering(Test::class) {
|
|
dependsOn(bundleTests)
|
|
|
|
testClassesDirs = files(tasks.test.get().testClassesDirs)
|
|
|
|
classpath =
|
|
// compiled test classes
|
|
bundleTests.get().outputs.files +
|
|
// fat Jar
|
|
tasks.shadowJar.get().outputs.files +
|
|
// test-only dependencies
|
|
// (test dependencies that are also main dependencies must already be contained in fat Jar;
|
|
// to verify that, we don't want to include them here)
|
|
(configurations.testRuntimeClasspath.get() - configurations.runtimeClasspath.get())
|
|
}
|
|
|
|
// TODO: the below snippet causes `./gradlew check` to fail specifically on
|
|
// `pkl-codegen-java:check`. Why?
|
|
// tasks.test {
|
|
// dependsOn(testFromJar)
|
|
// }
|
|
|
|
sourceSets.getByName("test") {
|
|
java.srcDir(layout.buildDirectory.dir("testConfigClasses/java"))
|
|
resources.srcDir(layout.buildDirectory.dir("testConfigClasses/resources"))
|
|
}
|
|
|
|
dependencies {
|
|
// "api" because ConfigEvaluator extends Evaluator
|
|
api(projects.pklCore)
|
|
|
|
implementation(libs.geantyref)
|
|
implementation(libs.msgpack)
|
|
|
|
testImplementation(libs.javaxInject)
|
|
|
|
firstPartySourcesJars(project(":pkl-core", "sourcesJar"))
|
|
|
|
pklCodegenJava(projects.pklCodegenJava)
|
|
}
|
|
|
|
tasks.shadowJar { archiveBaseName.set("pkl-config-java-all") }
|
|
|
|
publishing {
|
|
publications {
|
|
named<MavenPublication>("library") {
|
|
pom {
|
|
url.set("https://github.com/apple/pkl/tree/main/pkl-config-java")
|
|
description.set("Java config library based on the Pkl config language.")
|
|
}
|
|
}
|
|
|
|
named<MavenPublication>("fatJar") {
|
|
artifactId = "pkl-config-java-all"
|
|
pom {
|
|
url.set("https://github.com/apple/pkl/tree/main/pkl-config-java")
|
|
description.set(
|
|
"Shaded fat Jar for pkl-config-java, a Java config library based on the Pkl config language."
|
|
)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
signing { sign(publishing.publications["fatJar"]) }
|