mirror of
https://github.com/apple/pkl.git
synced 2026-04-28 11:17:17 +02:00
4faf35a66a
Motivation: buildSrc is a special-case legacy mechanism. Gradle recommends using an included build named build-logic instead: https://docs.gradle.org/current/userguide/best_practices_structuring_builds.html#favor_composite_builds Changes: - Rename buildSrc/ to build-logic/ - triggers reformatting - Replace occurrences of "buildSrc" with "build-logic" - Include the build-logic build in the main build (via settings.gradle.kts) - Apply convention plugins via plugin IDs instead of type-safe accessors - small tradeoff compared to buildSrc Result: - Faster and more isolated builds - Build logic behaves like a normal build, making it easier to evolve and reason about --------- Co-authored-by: Daniel Chao <dan.chao@apple.com>
54 lines
1.6 KiB
Kotlin
54 lines
1.6 KiB
Kotlin
/*
|
|
* Copyright © 2024-2026 Apple Inc. and the Pkl project authors. All rights reserved.
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* https://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
plugins {
|
|
id("pklAllProjects")
|
|
base
|
|
`maven-publish`
|
|
id("pklPublishLibrary")
|
|
id("pklSpotlessFormat")
|
|
signing
|
|
}
|
|
|
|
// create and publish a self-contained stdlib archive
|
|
// purpose is to provide non-jvm tools/projects with a versioned stdlib
|
|
val stdlibZip by
|
|
tasks.registering(Zip::class) {
|
|
destinationDirectory.set(layout.buildDirectory.dir("libs"))
|
|
archiveBaseName.set("pkl-stdlib")
|
|
archiveVersion.set(project.version as String)
|
|
into("org/pkl/stdlib") {
|
|
from(projectDir)
|
|
include("*.pkl")
|
|
}
|
|
}
|
|
|
|
tasks.assemble { dependsOn(stdlibZip) }
|
|
|
|
publishing {
|
|
publications {
|
|
create<MavenPublication>("stdlib") {
|
|
artifactId = "pkl-stdlib"
|
|
artifact(stdlibZip.flatMap { it.archiveFile })
|
|
pom {
|
|
description.set("Standard library for the Pkl programming language")
|
|
url.set("https://github.com/apple/pkl/tree/main/stdlib")
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
signing { sign(publishing.publications["stdlib"]) }
|