mirror of
https://github.com/apple/pkl.git
synced 2026-04-27 02:38:41 +02:00
4faf35a66a
Motivation: buildSrc is a special-case legacy mechanism. Gradle recommends using an included build named build-logic instead: https://docs.gradle.org/current/userguide/best_practices_structuring_builds.html#favor_composite_builds Changes: - Rename buildSrc/ to build-logic/ - triggers reformatting - Replace occurrences of "buildSrc" with "build-logic" - Include the build-logic build in the main build (via settings.gradle.kts) - Apply convention plugins via plugin IDs instead of type-safe accessors - small tradeoff compared to buildSrc Result: - Faster and more isolated builds - Build logic behaves like a normal build, making it easier to evolve and reason about --------- Co-authored-by: Daniel Chao <dan.chao@apple.com>
76 lines
2.3 KiB
Kotlin
76 lines
2.3 KiB
Kotlin
/*
|
|
* Copyright © 2024-2026 Apple Inc. and the Pkl project authors. All rights reserved.
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* https://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*/
|
|
// https://youtrack.jetbrains.com/issue/KTIJ-19369
|
|
import org.jetbrains.gradle.ext.ActionDelegationConfig
|
|
import org.jetbrains.gradle.ext.ActionDelegationConfig.TestRunner.PLATFORM
|
|
import org.jetbrains.gradle.ext.ProjectSettings
|
|
|
|
plugins {
|
|
id("pklAllProjects")
|
|
id("pklGraalVm")
|
|
|
|
alias(libs.plugins.ideaExt)
|
|
alias(libs.plugins.jmh) apply false
|
|
alias(libs.plugins.nexusPublish)
|
|
}
|
|
|
|
nexusPublishing {
|
|
repositories {
|
|
sonatype {
|
|
nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
|
|
snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
|
|
}
|
|
}
|
|
}
|
|
|
|
idea {
|
|
project {
|
|
this as ExtensionAware
|
|
configure<ProjectSettings> {
|
|
this as ExtensionAware
|
|
configure<ActionDelegationConfig> {
|
|
delegateBuildRunToGradle = true
|
|
testRunner = PLATFORM
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
val clean by tasks.existing { delete(layout.buildDirectory) }
|
|
|
|
val printVersion by tasks.registering { doFirst { println(buildInfo.pklVersion) } }
|
|
|
|
val message =
|
|
"""
|
|
====
|
|
Gradle version : ${gradle.gradleVersion}
|
|
Java version : ${System.getProperty("java.version")}
|
|
isParallel : ${gradle.startParameter.isParallelProjectExecutionEnabled}
|
|
maxWorkerCount : ${gradle.startParameter.maxWorkerCount}
|
|
Architecture : ${buildInfo.arch}
|
|
|
|
Project Version : ${project.version}
|
|
Pkl Version : ${buildInfo.pklVersion}
|
|
Pkl Non-Unique Version : ${buildInfo.pklVersionNonUnique}
|
|
Git Commit ID : ${buildInfo.commitId}
|
|
====
|
|
"""
|
|
|
|
val formattedMessage =
|
|
message.replace("\n====", "\n" + "=".repeat(message.lines().maxByOrNull { it.length }!!.length))
|
|
|
|
logger.info(formattedMessage)
|