Files
nix-config/modules/nixos/base/zram.nix
T

68 lines
2.9 KiB
Nix

{
lib,
config,
...
}:
let
cfg = config.modules.zram;
in
{
options.modules.zram.enable =
lib.mkEnableOption ''
zram in-memory swap device plus kernel sysctl tunings for it.
The sysctl tunings (swappiness=180 etc.) are designed for in-memory swap
devices only; they are gated behind this switch so that hosts which
disable zram (e.g. using a disk swapfile instead) also revert to the
kernel default swappiness instead of leaking zram tunings onto disk swap.
Enabled by default; hosts that want disk-only swap should set it to false.
''
// {
default = true;
};
config = lib.mkIf cfg.enable {
# Enable in-memory compressed devices and swap space provided by the zram kernel module.
# By enable this, we can store more data in memory instead of fallback to disk-based swap devices directly,
# and thus improve I/O performance when we have a lot of memory.
#
# https://www.kernel.org/doc/Documentation/blockdev/zram.txt
zramSwap = {
enable = true;
# one of "lzo", "lz4", "zstd"
algorithm = lib.mkDefault "zstd";
# Priority of the zram swap devices.
# It should be a number higher than the priority of your disk-based swap devices
# (so that the system will fill the zram swap devices before falling back to disk swap).
priority = lib.mkDefault 100;
# Maximum total amount of memory that can be stored in the zram swap devices (as a percentage of your total memory).
# Defaults to 1/2 of your total RAM. Run zramctl to check how good memory is compressed.
# This doesn't define how much memory will be used by the zram swap devices.
memoryPercent = lib.mkDefault 50;
};
# Optimizing swap on zram
boot.kernel.sysctl = {
# vm.swappiness - Controls kernel preference for swapping (range: 0-200, default: 60)
# For in-memory swap devices like zram/zswap, values above 100 are recommended.
"vm.swappiness" = lib.mkDefault 180;
# vm.watermark_boost_factor - Controls aggressiveness of memory reclaim (default: 15000)
# Setting to 0 disables watermark boost, preventing premature memory reclamation.
# This allows fuller memory utilization before the kernel starts reclaiming.
"vm.watermark_boost_factor" = lib.mkDefault 0;
# vm.watermark_scale_factor - Controls kswapd wakeup frequency (range: 1-1000, default: 10)
# Units are 1/10000 of total memory: the value below widens the low-to-min watermark gap and
# makes kswapd reclaim earlier, which avoids swap storms at the high swappiness above.
"vm.watermark_scale_factor" = lib.mkDefault 125;
# vm.page-cluster - Controls swap readahead (range: 0-6, default: 3)
# 0 means read only 1 page (2^0) at a time, disabling readahead.
# For low-latency devices like zram, readahead hurts performance by fetching unnecessary data.
"vm.page-cluster" = lib.mkDefault 0;
};
};
}