refactor: Use haumea for filesystem-based module system for flake outputs

refactor: Use hyphen(`-`) for variable names & folder names(except Python), replace all unserscore(`_`) with hyphen(`-`).

outputs/aarch64-linux/default.nix

@@ -0,0 +1,38 @@
+{
+  lib,
+  inputs,
+  ...
+} @ args: let
+  inherit (inputs) haumea;
+
+  # Contains all the flake outputs of this system architecture.
+  data = haumea.lib.load {
+    src = ./src;
+    inputs = args;
+  };
+  # nix file names is redundant, so we remove it.
+  dataWithoutPaths = builtins.attrValues data;
+
+  # Merge all the machine's data into a single attribute set.
+  outputs = {
+    nixosConfigurations = lib.attrsets.mergeAttrsList (map (it: it.nixosConfigurations or {}) dataWithoutPaths);
+    packages = lib.attrsets.mergeAttrsList (map (it: it.packages or {}) dataWithoutPaths);
+    # colmena contains some meta info, which need to be merged carefully.
+    colmena-meta = {
+      nodeNixpkgs = lib.attrsets.mergeAttrsList (map (it: it.colmena-meta.nodeNixpkgs or {}) dataWithoutPaths);
+      nodeSpecialArgs = lib.attrsets.mergeAttrsList (map (it: it.colmena-meta.nodeSpecialArgs or {}) dataWithoutPaths);
+    };
+    # colmena's per-machine data.
+    colmena = lib.attrsets.mergeAttrsList (map (it: it.colmena or {}) dataWithoutPaths);
+  };
+in
+  outputs
+  // {
+    inherit data; # for debugging purposes
+
+    # NixOS's unit tests.
+    # unit-tests = haumea.lib.loadEvalTests {
+    #   src = ./tests;
+    #   inputs = args;
+    # };
+  }

outputs/aarch64-linux/src/12kingdoms-rakushun.nix

@@ -0,0 +1,60 @@
+{
+  # NOTE: the args not used in this file CAN NOT be removed!
+  # because haumea pass argument lazily,
+  # and these arguments are used in the functions like `mylib.nixosSystem`, `mylib.colmenaSystem`, etc.
+  inputs,
+  lib,
+  mylib,
+  myvars,
+  system,
+  genSpecialArgs,
+  ...
+} @ args: let
+  # 楽俊, Rakushun
+  name = "rakushun";
+  tags = [name "aarch"];
+  ssh-user = "root";
+
+  modules = {
+    nixos-modules = map mylib.relativeToRoot [
+      "modules/nixos/server/server-aarch64.nix"
+      # host specific modules
+      "hosts/12kingdoms-${name}"
+    ];
+  };
+
+  inherit (inputs) nixos-rk3588;
+  baseSpecialArgs = genSpecialArgs system;
+
+  rk3588Pkgs = import nixos-rk3588.inputs.nixpkgs {inherit system;};
+  rk3588SpecialArgs = let
+    # using the same nixpkgs as nixos-rk3588
+    inherit (nixos-rk3588.inputs) nixpkgs;
+    # use aarch64-linux's native toolchain
+    pkgsKernel = import nixpkgs {inherit system;};
+  in
+    baseSpecialArgs
+    // {
+      inherit nixpkgs;
+      # Provide rk3588 inputs as special argument
+      rk3588 = {inherit nixpkgs pkgsKernel;};
+    };
+
+  rk3588SystemArgs =
+    modules
+    // args
+    // {
+      inherit (nixos-rk3588.inputs) nixpkgs; # or nixpkgs-unstable
+      specialArgs = rk3588SpecialArgs;
+    };
+in {
+  nixosConfigurations.${name} = mylib.nixosSystem rk3588SystemArgs;
+
+  colmena-meta = {
+    nodeSpecialArgs.${name} = rk3588SpecialArgs;
+    nodeNixpkgs.${name} = rk3588Pkgs;
+  };
+  colmena.${name} =
+    mylib.colmenaSystem
+    (rk3588SystemArgs // {inherit tags ssh-user;});
+}

outputs/aarch64-linux/src/12kingdoms-suzu.nix

@@ -0,0 +1,60 @@
+{
+  # NOTE: the args not used in this file CAN NOT be removed!
+  # because haumea pass argument lazily,
+  # and these arguments are used in the functions like `mylib.nixosSystem`, `mylib.colmenaSystem`, etc.
+  inputs,
+  lib,
+  mylib,
+  myvars,
+  system,
+  genSpecialArgs,
+  ...
+} @ args: let
+  # 大木 鈴, Ōki Suzu
+  name = "suzu";
+  tags = [name "aarch"];
+  ssh-user = "root";
+
+  modules = {
+    nixos-modules = map mylib.relativeToRoot [
+      "modules/nixos/server/server-aarch64.nix"
+      # host specific modules
+      "hosts/12kingdoms-${name}"
+    ];
+  };
+
+  inherit (inputs) nixos-rk3588;
+  baseSpecialArgs = genSpecialArgs system;
+
+  rk3588Pkgs = import nixos-rk3588.inputs.nixpkgs {inherit system;};
+  rk3588SpecialArgs = let
+    # using the same nixpkgs as nixos-rk3588
+    inherit (nixos-rk3588.inputs) nixpkgs;
+    # use aarch64-linux's native toolchain
+    pkgsKernel = import nixpkgs {inherit system;};
+  in
+    baseSpecialArgs
+    // {
+      inherit nixpkgs;
+      # Provide rk3588 inputs as special argument
+      rk3588 = {inherit nixpkgs pkgsKernel;};
+    };
+
+  rk3588SystemArgs =
+    modules
+    // args
+    // {
+      inherit (nixos-rk3588.inputs) nixpkgs; # or nixpkgs-unstable
+      specialArgs = rk3588SpecialArgs;
+    };
+in {
+  nixosConfigurations.${name} = mylib.nixosSystem rk3588SystemArgs;
+
+  colmena-meta = {
+    nodeSpecialArgs.${name} = rk3588SpecialArgs;
+    nodeNixpkgs.${name} = rk3588Pkgs;
+  };
+  colmena.${name} =
+    mylib.colmenaSystem
+    (rk3588SystemArgs // {inherit tags ssh-user;});
+}