dev: toolchain harmonization, additional checks and formatters

2026-07-16 17:51:14 +02:00 · 2026-06-29 19:48:38 +02:00
parent 1f0c7d4e51
commit de53020961
36 changed files with 1514 additions and 699 deletions
@@ -0,0 +1,42 @@
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoPatchelfHook,
+  openssl,
+  rocksdb,
+  surrealdbVersion ? (import ../../versions.nix).surrealdbVersion,
+  surrealdbBinaryHash ? (import ../../versions.nix).surrealdbBinaryHash,
+}:
+stdenv.mkDerivation {
+  pname = "surrealdb";
+  version = surrealdbVersion;
+
+  src = fetchurl {
+    url = "https://github.com/surrealdb/surrealdb/releases/download/v${surrealdbVersion}/surreal-v${surrealdbVersion}.linux-amd64.tgz";
+    hash = surrealdbBinaryHash;
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook ];
+  buildInputs = [
+    openssl
+    rocksdb
+    stdenv.cc.cc.lib
+  ];
+
+  sourceRoot = ".";
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 surreal $out/bin/surreal
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "SurrealDB prebuilt binary pinned for local dev and VM smoke tests";
+    homepage = "https://surrealdb.com/";
+    license = lib.licenses.bsl11;
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+}