dev: devenv deprecation

removed devenv in favor for plain nix, implemented using flake-parts
2026-07-03 03:21:37 +02:00 · 2026-06-28 22:23:03 +02:00
parent 0bba1f5a24
commit 1f0c7d4e51
17 changed files with 1012 additions and 720 deletions
@@ -0,0 +1,41 @@
+# Pinned SurrealDB release binary (avoids building nixpkgs surrealdb from source).
+{
+  lib,
+  stdenv,
+  fetchurl,
+  autoPatchelfHook,
+  openssl,
+  rocksdb,
+}:
+stdenv.mkDerivation {
+  pname = "surrealdb";
+  version = "2.6.5";
+
+  src = fetchurl {
+    url = "https://github.com/surrealdb/surrealdb/releases/download/v2.6.5/surreal-v2.6.5.linux-amd64.tgz";
+    hash = "sha256-kp1z9GxPtZ8jeBDm/m2lTBdWBk8+2NfR9qlw6P3zj7A=";
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook ];
+  buildInputs = [
+    openssl
+    rocksdb
+    stdenv.cc.cc.lib
+  ];
+
+  sourceRoot = ".";
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 surreal $out/bin/surreal
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "SurrealDB prebuilt binary pinned for local dev and VM smoke tests";
+    homepage = "https://surrealdb.com/";
+    license = lib.licenses.bsl11;
+    platforms = [ "x86_64-linux" ];
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+  };
+}